ASP Classic Linkify - Convert text links into Clickable URLs : Code Entry

Live Editing Disabled for Server-Side Example

HTML

<form action="Load.asp" method="post" name="http">
<textarea name="MyText1" cols="50" rows="4">This is the link to Coding Source: https://www.cffcs.com<br />And this is the link to Dark Effects Production: https://www.darkeffects.com</textarea>
<input type="submit" name="Submit" value="Process with http" />
</form>

Classic ASP

<%
Function Linkify(Text)

    Dim regEx, Match, Matches, patternURLs, patternAnchors, lCount, anchorCount, replacements

    patternURLs = "((http|ftp|https)(:\/\/[\w\-_]+)((\.[\w\-_]+)+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?)"
    patternAnchors = "<a[^>]*?>.*?</a>"

    Set replacements=Server.CreateObject("Scripting.Dictionary")

    ' Create the regular expression.
    Set regEx = New RegExp
    regEx.Pattern = patternAnchors
    regEx.IgnoreCase = True
    regEx.Global = True

    ' Do the search for anchors.
    Set Matches = regEx.Execute(Text)

    lCount = 0

    ' Iterate through the existing anchors and replace with a placeholder
    For Each Match in Matches
      key = "<#" & lCount & "#>"
      replacements.Add key, Match.Value
      Text = Replace(Text,Cstr(Match.Value),key)
      lCount = lCount+1
    Next

    anchorCount = lCount

    ' we now search for URls
    regEx.Pattern = patternURLs

    ' create anchors from URLs
    Text = regEx.Replace(Text, "<a href=""$1"">$1</a>")

    ' put back the originally existing anchors
    For lCount = 0 To anchorCount-1
        key = "<#" & lCount & "#>"
        Text = Replace(Text,key, replacements.Item(key))
    Next

    Linkify = Text

End Function
%>

Preview

Tags
Linkify in Classic ASP
Linkify() around your requested form element

About Company

Top Viewed Articles